Source file injector.ml

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
(*****************************************************************************)
(*                                                                           *)
(* Open Source License                                                       *)
(* Copyright (c) 2023 Functori, <contact@functori.com>                       *)
(*                                                                           *)
(* Permission is hereby granted, free of charge, to any person obtaining a   *)
(* copy of this software and associated documentation files (the "Software"),*)
(* to deal in the Software without restriction, including without limitation *)
(* the rights to use, copy, modify, merge, publish, distribute, sublicense,  *)
(* and/or sell copies of the Software, and to permit persons to whom the     *)
(* Software is furnished to do so, subject to the following conditions:      *)
(*                                                                           *)
(* The above copyright notice and this permission notice shall be included   *)
(* in all copies or substantial portions of the Software.                    *)
(*                                                                           *)
(* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR*)
(* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,  *)
(* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL   *)
(* THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER*)
(* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING   *)
(* FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER       *)
(* DEALINGS IN THE SOFTWARE.                                                 *)
(*                                                                           *)
(*****************************************************************************)

open Injector_sigs

type state = {
  cctxt : Client_context.full;
  fee_parameters : Configuration.fee_parameters;
  minimal_block_delay : int64;
  delay_increment_per_round : int64;
}

module Parameters :
  PARAMETERS
    with type state = state
     and type Tag.t = Operation_kind.t
     and type Operation.t = L1_operation.t = struct
  type nonrec state = state

  let events_section = ["smart_rollup_node"]

  module Tag : TAG with type t = Operation_kind.t = struct
    type t = Operation_kind.t

    let compare = Stdlib.compare

    let equal = Stdlib.( = )

    let hash = Hashtbl.hash

    let string_of_tag = Operation_kind.to_string

    let pp ppf t = Format.pp_print_string ppf (string_of_tag t)

    let encoding : t Data_encoding.t = Operation_kind.encoding
  end

  module Operation = L1_operation

  (* TODO: https://gitlab.com/tezos/tezos/-/issues/3459
     Very coarse approximation for the number of operation we
     expect for each block *)
  let table_estimated_size : Tag.t -> int = function
    | Publish -> 1
    | Add_messages -> 100
    | Cement -> 1
    | Timeout -> 1
    | Refute -> 1
    | Recover -> 1
    | Execute_outbox_message -> 1

  let operation_tag : Operation.t -> Tag.t = function
    | Add_messages _ -> Add_messages
    | Cement _ -> Cement
    | Publish _ -> Publish
    | Timeout _ -> Timeout
    | Refute _ -> Refute
    | Recover_bond _ -> Recover
    | Execute_outbox_message _ -> Execute_outbox_message

  let fee_parameter {fee_parameters; _} operation =
    let operation_kind = operation_tag operation in
    Operation_kind.Map.find operation_kind fee_parameters
    |> Option.value
         ~default:(Configuration.default_fee_parameter operation_kind)

  let safety_guard = function
    | Operation.Publish _ ->
        (* Gas consumption of commitment publication can increase if there are
           already commitments for the same level in the context. The value 300
           was inferred empirically by looking at gas consumption on a running
           rollup, and is sufficient to cover the difference in the case where a
           commitment for the same level already exists. *)
        Some 300
    | Timeout _ | Refute _ ->
        (* We increase safety of refutation game operations by precaution. *)
        Some 300
    | Add_messages _ | Cement _ | Recover_bond _ | Execute_outbox_message _ ->
        None

  let persist_operation (op : Operation.t) =
    match op with
    | Cement _ | Publish _
    (* Cement and Publish commitments don't need to be persisted as they are
       requeued by the node automatically. *)
    | Refute _ | Timeout _
    (* Refutation game operations don't need to be persisted as they are
       requeued by the node automatically depending on the state of the game on
       L1 on startup. *) ->
        false
    | Add_messages _ | Recover_bond _ | Execute_outbox_message _ -> true

  let retry_unsuccessful_operation _state (op : Operation.t) status =
    let open Lwt_syntax in
    match status with
    | Backtracked | Skipped | Other_branch ->
        (* Always retry backtracked or skipped operations, or operations that
           are on another branch because of a reorg:

           - Messages posted to an inbox should be re-emitted (i.e. re-queued)
             in case of a fork.

           - Timeout should be re-submitted as the timeout may be reached as well
             on the other branch.

           - Refutation should be re-submitted in case of fork.
             TODO: https://gitlab.com/tezos/tezos/-/issues/3459
             maybe check if game exists on other branch as well.
        *)
        return Retry
    | Failed error -> (
        (* TODO: https://gitlab.com/tezos/tezos/-/issues/4071
           Think about which operations should be retried and when. *)
        match op with
        | Cement _ | Publish _ ->
            (* Cement and Publish commitments can be forgotten to free up the
               injector as they are requeued by the node automatically. *)
            return Forget
        | Refute _ | Timeout _ | Add_messages _ | Recover_bond _
        | Execute_outbox_message _ -> (
            match classify_trace error with
            | Permanent | Outdated -> return Forget
            | Branch | Temporary -> return Retry))
    | Never_included ->
        (* Forget operations that are never included *)
        return Forget
end

include Injector_functor.Make (Parameters)

let check_and_add_pending_operation (mode : Configuration.mode)
    (operation : L1_operation.t) =
  let open Lwt_result_syntax in
  if Configuration.(can_inject mode (Parameters.operation_tag operation)) then
    let* hash = add_pending_operation operation in
    return (Some hash)
  else return None