Source file sapling_services.ml

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
(*****************************************************************************)
(*                                                                           *)
(* Open Source License                                                       *)
(* Copyright (c) 2019-2020 Nomadic Labs <contact@nomadic-labs.com>           *)
(*                                                                           *)
(* Permission is hereby granted, free of charge, to any person obtaining a   *)
(* copy of this software and associated documentation files (the "Software"),*)
(* to deal in the Software without restriction, including without limitation *)
(* the rights to use, copy, modify, merge, publish, distribute, sublicense,  *)
(* and/or sell copies of the Software, and to permit persons to whom the     *)
(* Software is furnished to do so, subject to the following conditions:      *)
(*                                                                           *)
(* The above copyright notice and this permission notice shall be included   *)
(* in all copies or substantial portions of the Software.                    *)
(*                                                                           *)
(* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR*)
(* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,  *)
(* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL   *)
(* THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER*)
(* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING   *)
(* FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER       *)
(* DEALINGS IN THE SOFTWARE.                                                 *)
(*                                                                           *)
(*****************************************************************************)

open Alpha_context

let custom_root =
  (RPC_path.(open_root / "context" / "sapling")
    : RPC_context.t RPC_path.context)

type diff_query = {
  offset_commitment : Int64.t option;
  offset_nullifier : Int64.t option;
}

module S = struct
  module Args = struct
    type ('query_type, 'output_type) t = {
      name : string;
      description : string;
      query : 'query_type RPC_query.t;
      output : 'output_type Data_encoding.t;
      f : context -> Sapling.Id.t -> 'query_type -> 'output_type tzresult Lwt.t;
    }

    let get_diff_query : diff_query RPC_query.t =
      let open RPC_query in
      query (fun offset_commitment offset_nullifier ->
          {offset_commitment; offset_nullifier})
      |+ opt_field
           ~descr:
             "Commitments and ciphertexts are returned from the specified \
              offset up to the most recent."
           "offset_commitment"
           RPC_arg.int64
           (fun {offset_commitment; _} -> offset_commitment)
      |+ opt_field
           ~descr:
             "Nullifiers are returned from the specified offset up to the most \
              recent."
           "offset_nullifier"
           RPC_arg.int64
           (fun {offset_nullifier; _} -> offset_nullifier)
      |> seal

    let encoding =
      let open Data_encoding in
      merge_objs (obj1 (req "root" Sapling.root_encoding)) Sapling.diff_encoding

    let get_diff =
      {
        name = "get_diff";
        description =
          "Returns the root and a diff of a state starting from an optional \
           offset which is zero by default.";
        query = get_diff_query;
        output = encoding;
        f =
          (fun ctxt id {offset_commitment; offset_nullifier} ->
            Sapling.get_diff ctxt id ?offset_commitment ?offset_nullifier ());
      }
  end

  let make_service Args.{name; description; query; output; f} =
    let path = RPC_path.(custom_root /: Sapling.rpc_arg / name) in
    let service = RPC_service.get_service ~description ~query ~output path in
    (service, fun ctxt id q () -> f ctxt id q)

  let get_diff = make_service Args.get_diff
end

let register () =
  let reg ~chunked (service, f) =
    Services_registration.register1 ~chunked service f
  in
  reg ~chunked:false S.get_diff

let mk_call1 (service, _f) ctxt block id q =
  RPC_context.make_call1 service ctxt block id q ()

let get_diff ctxt block id ?offset_commitment ?offset_nullifier () =
  mk_call1 S.get_diff ctxt block id {offset_commitment; offset_nullifier}