Source file ast.ml

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
(* This file is part of the Catala compiler, a specification language for tax
   and social benefits computation rules. Copyright (C) 2021 Inria, contributor:
   Denis Merigoux <denis.merigoux@inria.fr>

   Licensed under the Apache License, Version 2.0 (the "License"); you may not
   use this file except in compliance with the License. You may obtain a copy of
   the License at

   http://www.apache.org/licenses/LICENSE-2.0

   Unless required by applicable law or agreed to in writing, software
   distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
   WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
   License for the specific language governing permissions and limitations under
   the License. *)

open Catala_utils
open Shared_ast
module L = Lcalc.Ast

module FuncName =
  Uid.Gen
    (struct
      let style = Ocolor_types.(Fg (C4 green))
    end)
    ()

module VarName =
  Uid.Gen
    (struct
      let style = Ocolor_types.Default_fg
    end)
    ()

type operator = Shared_ast.lcalc Shared_ast.operator

type expr = naked_expr Mark.pos

and naked_expr =
  | EVar of VarName.t
  | EFunc of FuncName.t
  | EStruct of { fields : expr StructField.Map.t; name : StructName.t }
  | EStructFieldAccess of {
      e1 : expr;
      field : StructField.t;
      name : StructName.t;
    }
  | ETuple of expr list
  | ETupleAccess of { e1 : expr; index : int; typ : typ }
  | EInj of {
      e1 : expr;
      cons : EnumConstructor.t;
      name : EnumName.t;
      expr_typ : typ;
    }
  | EArray of expr list
  | ELit of lit
  | EPosLit
  | EApp of { f : expr; args : expr list; typ : typ; poly : bool }
      (** [typ] is the return type ; [poly] indicates if the function return is
          polymorphic (in which case the return value might need a cast) *)
  | EAppOp of { op : operator Mark.pos; args : expr list; tys : typ list }
  | EExternal of { modname : VarName.t Mark.pos; name : string Mark.pos }

type stmt =
  | SInnerFuncDef of { name : VarName.t Mark.pos; func : func }
  | SLocalDecl of { name : VarName.t Mark.pos; typ : typ }
  | SLocalInit of { name : VarName.t Mark.pos; typ : typ; expr : expr }
  | SLocalDef of { name : VarName.t Mark.pos; typ : typ; expr : expr }
  | SFatalError of { pos_expr : expr; error : Catala_runtime.error }
      (** [pos_expr] here is the position reified into an expression *)
  | SIfThenElse of { if_expr : expr; then_block : block; else_block : block }
  | SSwitch of {
      switch_var : VarName.t;
      switch_var_typ : typ;
      enum_name : EnumName.t;
      switch_cases : switch_case list;
    }
  | SReturn of expr
  | SAssert of { pos_expr : expr; expr : expr }
      (** [pos_expr] here is the position reified into an expression *)
  | SSpecialOp of special_operator

and special_operator = |
and block = stmt Mark.pos list

and switch_case = {
  case_block : block;
  payload_var_name : VarName.t;
  payload_var_typ : typ;
}

and func = {
  func_params : (VarName.t Mark.pos * typ) list;
  func_body : block;
  func_return_typ : typ;
}

type scope_body = {
  scope_body_name : ScopeName.t;
  scope_body_var : FuncName.t;
  scope_body_func : func;
  scope_body_visibility : visibility;
}

type code_item =
  | SVar of { var : VarName.t; expr : expr; typ : typ; visibility : visibility }
  | SFunc of { var : FuncName.t; func : func; visibility : visibility }
  | SScope of scope_body

type ctx = { decl_ctx : decl_ctx; modules : VarName.t ModuleName.Map.t }

type program = {
  ctx : ctx;
  code_items : code_item list;
  tests : code_item list * (ScopeName.t * block) list;
      (** The first element may contain lifted closures. It can be assumed to be
          empty when closure conversion is disabled. *)
  module_name : (ModuleName.t * module_intf_id) option;
}