Source file github_annotation.ml

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
(********************************************************************************)
(*  crs - A tool for managing code review comments embedded in source code      *)
(*  Copyright (C) 2024-2025 Mathieu Barbin <mathieu.barbin@gmail.com>           *)
(*                                                                              *)
(*  This file is part of crs.                                                   *)
(*                                                                              *)
(*  crs is free software; you can redistribute it and/or modify it under the    *)
(*  terms of the GNU Lesser General Public License as published by the Free     *)
(*  Software Foundation either version 3 of the License, or any later version,  *)
(*  with the LGPL-3.0 Linking Exception.                                        *)
(*                                                                              *)
(*  crs is distributed in the hope that it will be useful, but WITHOUT ANY      *)
(*  WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS   *)
(*  FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License and     *)
(*  the file `NOTICE.md` at the root of this repository for more details.       *)
(*                                                                              *)
(*  You should have received a copy of the GNU Lesser General Public License    *)
(*  and the LGPL-3.0 Linking Exception along with this library. If not, see     *)
(*  <http://www.gnu.org/licenses/> and <https://spdx.org>, respectively.        *)
(********************************************************************************)

module Severity = struct
  type t =
    | Error
    | Warning
    | Notice
  [@@deriving sexp_of]

  let to_string = function
    | Error -> "error"
    | Warning -> "warning"
    | Notice -> "notice"
  ;;
end

type t =
  { loc : Loc.t
  ; severity : Severity.t
  ; title : string
  ; message : string
  }
[@@deriving sexp_of]

let create ~loc ~severity ~title ~message = { loc; severity; title; message }

let to_loc_fields_internal ~loc =
  let column (pos : Lexing.position) = pos.pos_cnum - pos.pos_bol + 1 in
  let start_pos = Loc.start loc in
  let stop_pos = Loc.stop loc in
  [ "file", Fpath.to_string (Loc.path loc)
  ; "line", Int.to_string start_pos.pos_lnum
  ; "col", Int.to_string (column start_pos)
  ; "endLine", Int.to_string stop_pos.pos_lnum
  ; "endColumn", Int.to_string (column stop_pos)
  ]
;;

let to_loc_fields ~loc = if Loc.is_none loc then [] else to_loc_fields_internal ~loc

let to_string { loc; severity; title; message } =
  let fields = to_loc_fields ~loc @ [ "title", title ] in
  String.concat
    ~sep:""
    [ "::"
    ; Severity.to_string severity
    ; " "
    ; List.map fields ~f:(fun (field, value) -> Printf.sprintf "%s=%s" field value)
      |> String.concat ~sep:","
    ; "::"
    ; String.substr_replace_all message ~pattern:"\n" ~with_:"%0A"
    ]
;;