Source file instrumentation.ml

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
(*********************************************************************************)
(*  Dunolint - A tool to lint and help manage files in dune projects             *)
(*  Copyright (C) 2024-2025 Mathieu Barbin <mathieu.barbin@gmail.com>            *)
(*                                                                               *)
(*  This file is part of Dunolint.                                               *)
(*                                                                               *)
(*  Dunolint is free software; you can redistribute it and/or modify it          *)
(*  under the terms of the GNU Lesser General Public License as published by     *)
(*  the Free Software Foundation either version 3 of the License, or any later   *)
(*  version, with the LGPL-3.0 Linking Exception.                                *)
(*                                                                               *)
(*  Dunolint is distributed in the hope that it will be useful, but WITHOUT      *)
(*  ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or        *)
(*  FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License  *)
(*  and the file `NOTICE.md` at the root of this repository for more details.    *)
(*                                                                               *)
(*  You should have received a copy of the GNU Lesser General Public License     *)
(*  and the LGPL-3.0 Linking Exception along with this library. If not, see      *)
(*  <http://www.gnu.org/licenses/> and <https://spdx.org>, respectively.         *)
(*********************************************************************************)

type t = { mutable backend : Dune.Instrumentation.Backend.Name.t } [@@deriving sexp_of]

let create ~backend = { backend }
let field_name = "instrumentation"

let read ~sexps_rewriter ~field =
  let args = Dunolinter.Sexp_handler.get_args ~field_name ~sexps_rewriter ~field in
  match
    List.find_map args ~f:(function
      | List [ Atom "backend"; Atom name ] ->
        Some (Dune.Instrumentation.Backend.Name.v name)
      | _ -> None)
  with
  | Some backend -> create ~backend
  | None ->
    let loc = Sexps_rewriter.loc sexps_rewriter field in
    Err.raise
      ~loc
      Pp.O.
        [ Pp.text "Required "
          ++ Pp_tty.kwd (module String) "backend"
          ++ Pp.text " value in instrumentation."
        ]
;;

let write (t : t) =
  Sexp.List
    [ Atom field_name
    ; List
        [ Atom "backend"; Atom (Dune.Instrumentation.Backend.Name.to_string t.backend) ]
    ]
;;

let rewrite t ~sexps_rewriter ~field =
  let args = Dunolinter.Sexp_handler.get_args ~field_name ~sexps_rewriter ~field in
  let file_rewriter = Sexps_rewriter.file_rewriter sexps_rewriter in
  List.iter args ~f:(function
    | List [ Atom "backend"; (Atom _ as name) ] ->
      let range = Sexps_rewriter.range sexps_rewriter name in
      File_rewriter.replace
        file_rewriter
        ~range
        ~text:(Dune.Instrumentation.Backend.Name.to_string t.backend)
    | _ -> ())
;;

type predicate = Dune.Instrumentation.Predicate.t

let eval t ~predicate =
  match (predicate : predicate) with
  | `backend name ->
    Dune.Instrumentation.Backend.Name.equal name t.backend |> Dunolint.Trilang.const
;;

let rec enforce t ~condition =
  match (condition : predicate Blang.t) with
  | Base (`backend name) -> t.backend <- name
  | (And _ | If _ | True | False | Not _ | Or _) as condition ->
    Dunolinter.Linter.enforce_blang
      (module Dune.Instrumentation.Predicate)
      t
      ~condition
      ~eval
      ~enforce
;;

let default_backend = Dune.Instrumentation.Backend.Name.v "bisect_ppx"

let initialize ~condition =
  let backend =
    List.find_map
      (Dunolinter.Linter.at_positive_enforcing_position condition)
      ~f:(function `backend name -> Some name)
    |> Option.value ~default:default_backend
  in
  { backend }
;;