Source file `event.ml`

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
type 'a t = {
  poll: unit -> 'a Exn_bt.result option;
  wait: (unit -> unit) -> Cancel_handle.t;
}

type 'ret branch = When : 'a t * ('a -> 'ret) -> 'ret branch

let rec select_rec_ brs =
  let rec poll_list_ = function
    | When (ev, f) :: tl ->
      (* see if [ev] is ready *)
      (match ev.poll () with
      | Some (Ok x) -> (f [@tailcall]) x
      | Some (Error ebt) -> Exn_bt.raise ebt
      | None -> poll_list_ tl)
    | [] ->
      (* no branch worked. Now let's wait. *)
      let cancel_handlers = ref [] in
      Fiber.suspend ~before_suspend:(fun ~wakeup ->
          (* make sure we call [wakeup] only once *)
          let woken_up = ref false in
          let wakeup_once () =
            if not !woken_up then (
              woken_up := true;
              wakeup ()
            )
          in

          List.iter
            (fun (When (ev, _)) ->
              let cancel = ev.wait wakeup_once in
              if cancel != Cancel_handle.dummy then
                cancel_handlers := cancel :: !cancel_handlers)
            brs);

      List.iter (fun cb -> Cancel_handle.cancel cb) !cancel_handlers;

      (* poll again *)
      (select_rec_ [@tailcall]) brs
  in

  poll_list_ brs

let[@inline] select (brs : _ branch list) =
  match brs with
  | [] -> assert false
  | brs -> select_rec_ brs