Source file SLiteral.ml

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169

(* This file is free software, part of Logtk. See file "license" for more details. *)

(** {1 Simple Literal} *)

module T = TypedSTerm
module F = T.Form
module US = Unif_subst

type form = TypedSTerm.t
type term = TypedSTerm.t

exception NotALit of form

let () = Printexc.register_printer
    (function
      | NotALit f -> Some (CCFormat.sprintf "@[<2>formula@ @[%a@]@ is not a lit@]" T.pp f)
      | _ -> None)

let not_lit f = raise (NotALit f)

type +'t t =
  | True
  | False
  | Atom of 't * bool
  | Eq of 't * 't
  | Neq of 't * 't

type 'a lit = 'a t

let map ~f = function
  | True -> True
  | False -> False
  | Atom (t, b) -> Atom (f t, b)
  | Eq (a,b) -> Eq (f a, f b)
  | Neq (a,b) -> Neq (f a, f b)

let fold f acc = function
  | True
  | False -> acc
  | Atom (t, _) -> f acc t
  | Eq (a,b)
  | Neq (a,b) -> f (f acc a) b

let iter ~f = function
  | True
  | False -> ()
  | Atom (t, _) -> f t
  | Eq (a,b)
  | Neq (a,b) -> f a; f b

let to_iter l f = match l with
  | True
  | False -> ()
  | Atom (t, _) -> f t
  | Eq (a,b)
  | Neq (a,b) -> f a; f b

let equal eq a b = match a, b with
  | True, True
  | False, False -> true
  | Atom (t1,b1), Atom (t2,b2) -> b1=b2 && eq t1 t2
  | Eq (a1,a2), Eq (b1,b2)
  | Neq (a1,a2), Neq (b1,b2) ->
    (eq a1 b1 && eq a2 b2) ||
    (eq a1 b2 && eq a2 b1)
  | True, _
  | False, _
  | Atom _, _
  | Eq _, _
  | Neq _, _ -> false

let true_ = True
let false_ = False
let eq a b = Eq (a,b)
let neq a b = Neq (a,b)
let atom a b = Atom (a,b)
let atom_true a = atom a true
let atom_false a = atom a false

let is_true = function True -> true | _ -> false
let is_false = function False -> true | _ -> false

let sign = function
  | True
  | Eq _ -> true
  | Atom (_, b) -> b
  | Neq _
  | False -> false

let is_pos l = sign l
let is_neg l = not (sign l)

let negate = function
  | True -> False
  | False -> True
  | Atom (t,sign) -> atom t (not sign)
  | Eq (a,b) -> neq a b
  | Neq (a,b) -> eq a b

let fpf = Format.fprintf

let to_form = function
  | True -> F.true_
  | False -> F.false_
  | Atom (t, true) -> t
  | Atom (t, false) -> F.not_ t
  | Eq (a,b) -> F.eq a b
  | Neq (a,b) -> F.neq a b

let of_form f = match F.view f with
  | F.Not f' ->
    begin match F.view f' with
      | F.Atom t -> Atom (t, false)
      | _ -> not_lit f
    end
  | F.Eq (t1,t2) -> Eq (t1,t2)
  | F.Neq (t1,t2) -> Neq (t1,t2)
  | F.Atom t -> Atom (t,true)
  | F.True -> True
  | F.False -> False
  | F.Or _
  | F.And _
  | F.Equiv _
  | F.Xor _
  | F.Imply _
  | F.Forall _
  | F.Exists _ -> not_lit f

let pp ppt out = function
  | True -> fpf out "true"
  | False -> fpf out "false"
  | Atom (t, true) -> ppt out t
  | Atom (t, false) -> fpf out "@[<2>¬@ @[%a@]@]" ppt t
  | Eq (t1,t2) -> fpf out "@[%a@ =@ %a@]" ppt t1 ppt t2
  | Neq (t1,t2) -> fpf out "@[%a@ ≠@ %a@]" ppt t1 ppt t2


let to_string ppt = CCFormat.to_string (pp ppt)

module TPTP = struct
  let pp ppt out = function
    | True -> fpf out "$true"
    | False -> fpf out "$false"
    | Atom (t, true) -> ppt out t
    | Atom (t, false) -> fpf out "@[<2>~@ @[%a@]@]" ppt t
    | Eq (t1,t2) -> fpf out "@[%a@ =@ %a@]" ppt t1 ppt t2
    | Neq (t1,t2) -> fpf out "@[%a@ !=@ %a@]" ppt t1 ppt t2

  let to_string ppt = CCFormat.to_string (pp ppt)
end

module ZF = struct
  let pp ppt out = function
    | True -> fpf out "true"
    | False -> fpf out "false"
    | Atom (t, true) -> ppt out t
    | Atom (t, false) -> fpf out "@[<2>~@ @[%a@]@]" ppt t
    | Eq (t1,t2) -> fpf out "@[%a@ =@ %a@]" ppt t1 ppt t2
    | Neq (t1,t2) -> fpf out "@[%a@ !=@ %a@]" ppt t1 ppt t2

  let to_string ppt = CCFormat.to_string (pp ppt)
end

let pp_in o pp_x = match o with
  | Output_format.O_zf -> ZF.pp pp_x
  | Output_format.O_normal -> pp pp_x
  | Output_format.O_tptp -> TPTP.pp pp_x
  | Output_format.O_none -> (fun _ _ -> ())