Source file `schema.ml`

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
open Printf
open Util

type t =
  { raw            : Swagger_j.schema
  ; reference_base : string
  ; reference_root : Mod.t
  }

let create ~reference_base ~reference_root raw =
  { raw; reference_base; reference_root }

let reference t =
  t.raw.ref

let rec kind_to_string t =
  let reference_base = t.reference_base in
  let reference_root = t.reference_root in
  match t.raw.ref with
  | Some r -> Mod.reference_type ~reference_base ~reference_root r
  | None ->
      match some t.raw.kind with
      | `String  -> "string"
      | `Number  -> "float"
      | `Integer -> "int"
      | `Boolean -> "bool"
      | `Object  ->
          let open Swagger_j in
          (match t.raw.additional_properties with
          | Some props ->
              (match props.ref, props.kind with
              | Some r, _ -> sprintf "%s.Object.t" (Mod.reference_module ~reference_base ~reference_root r)
              | None, Some `String -> "Object.Of_strings.t"
              | None, Some `Number -> "Object.Of_floats.t"
              | None, Some `Integer -> "Object.Of_ints.t"
              | None, Some `Boolean -> "Object.Of_bools.t"
              | None, _ -> sprintf "(string * %s) list" (kind_to_string (create ~reference_base ~reference_root props)))
          | None ->
              failwith ("Schema.kind_to_string: object without "
                        ^ "additional_properties"))
      | `Array   ->
          let open Swagger_j in
          match t.raw.items with
          | Some s ->
              let s = create ~reference_base ~reference_root s in
              kind_to_string s ^ " list"
          | None ->
              failwith ("Schema.kind_to_string: array type must have an " ^
                        "'items' field")

let to_string t =
  let reference_base = t.reference_base in
  let reference_root = t.reference_root in
  match t.raw.ref with
  | Some r -> Mod.reference_type ~reference_base ~reference_root r
  | None -> kind_to_string t