Source file `ticket.ml`

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
open Capnp_rpc_lwt

type t = Raw.Service.Ticket.t Capability.t

let ( >>!= ) = Lwt_result.bind

let local ~job ~cancel ~release =
  let module X = Raw.Service.Ticket in
  X.local @@ object
    inherit X.service

    method job_impl _params release_param_caps =
      let open X.Job in
      release_param_caps ();
      let response, results = Service.Response.create Results.init_pointer in
      Results.job_set results (Some job);
      Service.return response

    method cancel_impl _params release_param_caps =
      release_param_caps ();
      Service.return_lwt @@ fun () ->
      cancel () >>!= fun () ->
      let response = Service.Response.create_empty () in
      Lwt_result.return response

    (* Note: we keep job alive until *after* calling [release]. *)
    method! release =
      release ();
      Capability.dec_ref job
  end

module X = Raw.Client.Ticket

let job t =
  let open X.Job in
  let request = Capability.Request.create_no_args () in
  Capability.call_for_caps t method_id request Results.job_get_pipelined

let cancel t =
  let open X.Cancel in
  let request = Capability.Request.create_no_args () in
  Capability.call_for_unit t method_id request