Source file `num_status.ml`

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
(*******************************************************************************)
(*  Volgo - a Versatile OCaml Library for Git Operations                       *)
(*  Copyright (C) 2024-2025 Mathieu Barbin <mathieu.barbin@gmail.com>          *)
(*                                                                             *)
(*  This file is part of Volgo.                                                *)
(*                                                                             *)
(*  Volgo is free software; you can redistribute it and/or modify it under     *)
(*  the terms of the GNU Lesser General Public License as published by the     *)
(*  Free Software Foundation either version 3 of the License, or any later     *)
(*  version, with the LGPL-3.0 Linking Exception.                              *)
(*                                                                             *)
(*  Volgo is distributed in the hope that it will be useful, but WITHOUT ANY   *)
(*  WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS  *)
(*  FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License and    *)
(*  the file `NOTICE.md` at the root of this repository for more details.      *)
(*                                                                             *)
(*  You should have received a copy of the GNU Lesser General Public License   *)
(*  and the LGPL-3.0 Linking Exception along with this library. If not, see    *)
(*  <http://www.gnu.org/licenses/> and <https://spdx.org>, respectively.       *)
(*******************************************************************************)

module Status_code = struct
  module T = struct
    [@@@coverage off]

    type t =
      | Dash
      | Num of int
      | Other of string

    let to_dyn = function
      | Dash -> Dyn.Variant ("Dash", [])
      | Num n -> Dyn.Variant ("Num", [ Dyn.int n ])
      | Other s -> Dyn.Variant ("Other", [ Dyn.string s ])
    ;;

    let sexp_of_t t = Dyn.to_sexp (to_dyn t)
  end

  include T

  let parse = function
    | "-" -> Dash
    | status ->
      (match Int.of_string_opt status with
       | Some n when n >= 0 -> Num n
       | Some _ | None -> Other status)
  ;;
end

let parse_line_exn ~line : Vcs.Num_status.Change.t =
  match
    Vcs.Private.try_with (fun () ->
      match String.split line ~on:'\t' with
      | [] -> assert false
      | [ _ ] | [ _; _ ] | _ :: _ :: _ :: _ :: _ ->
        raise (Err.E (Err.create [ Pp.text "Unexpected output from git diff." ]))
      | [ insertions; deletions; munged_path ] ->
        { Vcs.Num_status.Change.key = Munged_path.parse_exn munged_path
        ; num_stat =
            (match Status_code.parse insertions, Status_code.parse deletions with
             | Dash, Dash -> Binary_file
             | Num insertions, Num deletions ->
               Num_lines_in_diff { insertions; deletions }
             | insertions, deletions ->
               raise
                 (Err.E
                    (Err.create
                       [ Pp.text "Unexpected output from git diff."
                       ; Err.sexp
                           (Sexp.List
                              [ sexp_field (module Status_code) "insertions" insertions
                              ; sexp_field (module Status_code) "deletions" deletions
                              ])
                       ])))
        })
  with
  | Ok t -> t
  | Error err ->
    raise
      (Err.E
         (Err.add_context
            err
            [ Err.sexp
                (Sexp.List
                   [ Sexp.Atom "Volgo_git_backend.Num_status.parse_line_exn"
                   ; sexp_field (module String) "line" line
                   ])
            ]))
;;

let parse_lines_exn ~lines = List.map lines ~f:(fun line -> parse_line_exn ~line)

module Make (Runtime : Runtime.S) = struct
  type t = Runtime.t

  let num_status t ~repo_root ~(changed : Vcs.Name_status.Changed.t) =
    let changed_param =
      match changed with
      | Between { src; dst } ->
        Printf.sprintf "%s..%s" (src |> Vcs.Rev.to_string) (dst |> Vcs.Rev.to_string)
    in
    Runtime.git
      t
      ~cwd:(repo_root |> Vcs.Repo_root.to_absolute_path)
      ~args:[ "diff"; "--numstat"; changed_param ]
      ~f:(fun output ->
        let open Result.Syntax in
        let* stdout = Vcs.Git.Result.exit0_and_stdout output in
        Vcs.Private.try_with (fun () ->
          parse_lines_exn ~lines:(String.split_lines stdout)))
  ;;
end