Source file `column_intf.ml`

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
open! Core
open! Bonsai_web
open Incr_map_collate

module type S = sig
  type t
  type key
  type data

  val headers : t -> Header_tree.t Computation.t

  val instantiate_cells
    :  t
    -> (key, 'cmp) Bonsai.comparator
    -> (key * data) Map_list.t Value.t
    -> (key * Vdom.Node.t list) Map_list.t Computation.t
end

module type S_with_sorter = sig
  type t
  type key
  type data

  val headers_and_sorters
    :  t
    -> int Sortable_header.t Value.t
    -> ((key * data -> key * data -> int) Int.Map.t * Header_tree.t) Computation.t

  val instantiate_cells
    :  t
    -> (key, 'cmp) Bonsai.comparator
    -> (key * data) Map_list.t Value.t
    -> (key * Vdom.Node.t list) Map_list.t Computation.t
end

type ('key, 'data) t =
  | T :
      { value : 'a
      ; vtable : (module S with type t = 'a and type key = 'key and type data = 'data)
      }
      -> ('key, 'data) t

type ('key, 'data) with_sorter =
  | Y :
      { value : 'a
      ; vtable :
          (module S_with_sorter with type t = 'a and type key = 'key and type data = 'data)
      }
      -> ('key, 'data) with_sorter